MENU
Sound Design in Csound: Simple Whoosh sound effects

Sound Design in Csound: Simple Whoosh sound effects

 

Whoosh sound effects can be created from any recorded or synthesized noisy source. Whooshes have many possible applications and therefore are a very useful addition to your sound design palette. They can be used in video editing, game sound design, advertisment, trailers and more. They can be synthesized through subtractive synthesis in Csound with just a few lines of code. Here is an example of what they sound like:

 

 

 

 

Below is the Csound instrument that I have created to synthesize the whoosh sound effect:

 

Orchestra:
;.......................................................
;Simple Whoosh Synthesizer
;Author: Michele Pizzi
;.......................................................
sr = 48000
kr = 4800
ksmps = 10
nchnls = 2

instr 1

iamp       = p4
ilowpass   = p5
ireson     = p6
ibandreson = p7
imix       = p8

iduration  = p3*0.75


kenv expseg 0.00000000001,iduration*0.5,1,iduration*0.5,0.00000000001
krise expseg 0.00000000001,iduration*0.5,(ireson/100)*60,iduration*0.5,0.00000000001

anoisegen rand iamp*kenv                                             ;noise generator

af1 tone anoisegen,ilowpass                                          ;lowpass filter   in parallel    

af2 reson anoisegen,ireson+krise,ibandreson                          ;resonant filter in parallel

afilters = (af1+af2)                                                 ;mixes two filters

aout  balance afilters,anoisegen                                     ;adjusts sum output two filters to amp noise generator

aL,aR reverbsc aout,aout,0.4,5000                                    ;reverb unit

arevL = (aL*imix)                                                    ;adjusts level reverb unit according to imix variable
arevR = (aR*imix)

outs aout*(1-imix)+arevL,aout*(1-imix)+arevR                         ;mixes reverb with dry signal
endin

Score:

;instrument   start       duration     amp      lp frequency       reson cf        band reson     mix reverb
i1            0           3.3          21000    650                190             50             0.25

 

With simple changes to the parameters we can generate a variety of sound effects of different durations, timbre and amount of reverb.

If we need a longer or shorter reverb tail, we can create a new variable for reverb time (e.g. irevdecay = p9) and copy the name of the variable in the third argument of reverbsc. Or simply copy and paste the same instrument with a different instr number (e.g. instr 2) and change the reverb time in reverbsc.

 

See also

Ask
Print